**************************************************************************
      * DBG030DF: Display Document text
      * Copyright (C) 2000  Martin Rowe  <martin@dbg400.net>
      *
      * This program is free software; you can redistribute it and/or modify
      * it under the terms of the GNU General Public License as published by
      * the Free Software Foundation; either version 2 of the License, or
      * (at your option) any later version.
      *
      * This program is distributed in the hope that it will be useful,
      * but WITHOUT ANY WARRANTY; without even the implied warranty of
      * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
      * GNU General Public License for more details.
      *
      * You should have received a copy of the GNU General Public License
      * along with this program; if not, write to the Free Software Foundation,
      * Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307   USA
      **************************************************************************
     A*%%TS  SD  19980706  154553  MROWE       REL-V3R7M0  5716-PW1
     A*%%EC
     A                                      DSPSIZ(24 80 *DS3)
     A                                      PRINT(29)
     A                                      ALTHELP
     A                                      HELP
     A          R SFL                       SFL
     A*%%TS  SD  19941202  144843  MROWE       REL-V3R0M5  5763-PW1
     A            DFTEXT        79   O  4  2
     A          R SFLCTL                    SFLCTL(SFL)
     A*%%TS  SD  19960327  171046  MROWE       REL-V3R1M0  5763-PW1
     A                                      SFLSIZ(0019)
     A                                      SFLPAG(0018)
     A                                      CA03(03 'Exit')
     A  50                                  CF06(06 'Edit')
     A                                      CF12(12 'Previous')
     A                                      CF14(14 'Find options')
     A                                      CF16(16 'Find')
     A                                      OVERLAY
     A  36                                  SFLDSP
     A                                      SFLDSPCTL
     A N36                                  SFLCLR
     A  35                                  SFLEND(*MORE)
     A N36                                  ERASE(SFL)
     A                                      CSRLOC(CSRLIN CSRCOL)
     A                                      RTNCSRLOC(*WINDOW &CSRLIN &CSRCOL)
     A            SFPAGE         4S 0H      SFLRCDNBR
     A            CSRLIN         3S 0H
     A            CSRCOL         3S 0H
     A            COMPNY        40A  O  1  2DSPATR(RI)
     A                                  1 43USER
     A                                      DSPATR(RI)
     A                                  1 54SYSNAME
     A                                      DSPATR(RI)
     A                                  1 63DATE
     A                                      EDTCDE(Y)
     A                                      DSPATR(RI)
     A                                  1 72' DBG030R4'
     A                                      DSPATR(RI)
     A                                  2  2' '
     A                                      DSPATR(RI)
     A                                  2  4'View document'
     A                                      DSPATR(HI)
     A            P#DOCD        10A  O  2 18
     A            P#TITL        50A  O  2 29
     A                                  2 80' '
     A                                      DSPATR(RI)
     A                                  3  2'                                  -
     A                                                                         -
     A                                                '
     A                                      DSPATR(RI)
     A          R FOOTER
     A*%%TS  SD  19980706  154553  MROWE       REL-V3R7M0  5716-PW1
     A                                      OVERLAY
     A                                      HLPTITLE('View Document Text')
     A          H                           HLPPNLGRP(VIEWTXT DBG030PG)
     A                                      HLPARA(01 002 24 080)
     A                                 23  2'F1=Help'
     A                                      COLOR(BLU)
     A  50                             23 12'F6=Edit document'
     A                                      COLOR(BLU)
     A N50                             23 12'F12=Previous'
     A                                      COLOR(BLU)
     A N50                             23 27'F14=Find options'
     A                                      COLOR(BLU)
     A  50                             23 31'F12=Previous'
     A                                      COLOR(BLU)
     A  50                             23 46'F14=Find options'
     A                                      COLOR(BLU)
     A N50                             23 46'F16=Find'
     A                                      COLOR(BLU)
     A  50                             23 65'F16=Find'
     A                                      COLOR(BLU)
     A                                 23 75'Print'
     A                                      COLOR(BLU)
     A          R WINDOW
     A*%%TS  SD  19980706  144222  MROWE       REL-V3R7M0  5716-PW1
     A                                      CF12(12 'Previous')
     A                                      CF16(16 'Find')
     A                                      WINDOW(10 15 4 45)
     A                                      HLPTITLE('View Document Text')
     A          H                           HLPPNLGRP(FKEY14 DBG030PG)
     A                                      HLPARA(01 002 4 045)
     A                                  1  1'Find string:'
     A                                      DSPATR(HI)
     A            FINDSTRING    25   B  1 14CHECK(LC)
     A                                  2  1'Type of match:'
     A                                      DSPATR(HI)
     A            MATCHTYPE      1   B  2 16VALUES('1' '2')
     A                                  2 18'(1=Same case, 2=Ignore case)'
     A                                      COLOR(BLU)
     A                                  3  1'F1=Help'
     A                                      COLOR(BLU)
     A                                  3 11'F3=Exit'
     A                                      COLOR(BLU)
     A                                  3 21'F12=Previous'
     A                                      COLOR(BLU)
     A                                  3 36'Enter=Find'
     A                                      COLOR(BLU)
     A*
     A          R MSFL                      SFL
     A                                      SFLMSGRCD(24)
     A            MSGKEY                    SFLMSGKEY
     A            PGM                       SFLPGMQ
     A*
     A          R MSFLC                     SFLCTL(MSFL)
     A                                      OVERLAY
     A                                      SFLDSP
     A                                      SFLDSPCTL
     A                                      SFLINZ
     A  26
     AON26                                  SFLEND
     A                                      SFLSIZ(0002)
     A                                      SFLPAG(0001)
     A            PGM                       SFLPGMQ