A*%%TS  SD  20010223  145932  MROWE       REL-V4R4M0  5769-PW1
     A**************************************************************************
     A* DBG200DF: Select Field Mapping Options
     A* Copyright (C) 2001  Martin Rowe  <martin@dbg400.net>
     A*
     A* This program is free software; you can redistribute it and/or modify
     A* it under the terms of the GNU General Public License as published by
     A* the Free Software Foundation; either version 2 of the License, or
     A* (at your option) any later version.
     A*
     A* This program is distributed in the hope that it will be useful,
     A* but WITHOUT ANY WARRANTY; without even the implied warranty of
     A* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
     A* GNU General Public License for more details.
     A*
     A* You should have received a copy of the GNU General Public License
     A* along with this program; if not, write to the Free Software Foundation,
     A* Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307   USA
     A**************************************************************************
     A*%%EC
     A                                      DSPSIZ(24 80 *DS3)
     A                                      PRINT(29)
     A                                      ALTHELP
     A                                      HELP
     A          R SFL                       SFL
     A*%%TS  SD  20010223  145330  MROWE       REL-V4R4M0  5769-PW1
     A            DA_IFLD        1A  P
     A            S_EDIT         1A  B  5  3VALUES('2' ' ')
     A            S_IFLD        10A  O  5  7DSPATR(&DA_IFLD)
     A            S_IITP         1A  O  5 18
     A            S_INLN         4A  O  5 20
     A            S_INSC         1A  O  5 25
     A            S_ITXT        52A  O  5 28
     A          R SFLCTL                    SFLCTL(SFL)
     A*%%TS  SD  20010223  145330  MROWE       REL-V4R4M0  5769-PW1
     A                                      SFLSIZ(0018)
     A                                      SFLPAG(0017)
     A                                      CA03(03 'Exit')
     A                                      CF12(12 'Previous')
     A                                      OVERLAY
     A  36                                  SFLDSP
     A                                      SFLDSPCTL
     A N36                                  SFLCLR
     A  35                                  SFLEND(*MORE)
     A N36                                  ERASE(SFL)
     A                                      CSRLOC(CSRLIN     CSRCOL)
     A                                      RTNCSRLOC(*WINDOW &CSRLIN &CSRCOL)
     A            SFPAGE         4S 0H      SFLRCDNBR
     A            CSRLIN         3S 0H
     A            CSRCOL         3S 0H
     A            COMPNY        40A  O  1  2DSPATR(RI)
     A                                  1 43USER
     A                                      DSPATR(RI)
     A                                  1 54SYSNAME
     A                                      DSPATR(RI)
     A                                  1 63DATE
     A                                      EDTCDE(Y)
     A                                      DSPATR(RI)
     A                                  1 72' DBG200R4'
     A                                      DSPATR(RI)
     A                                  2  2' '
     A                                      DSPATR(RI)
     A                                  2  4'Field mapping'
     A                                      DSPATR(HI)
     A            P_FILE        10A  O  2 18
     A            P_TEXT        50A  O  2 29
     A                                  2 80' '
     A                                      DSPATR(RI)
     A                                  3  2'                                  -
     A                                                                         -
     A                                                '
     A                                      DSPATR(RI)
     A                                  4  2'Opt'
     A                                      DSPATR(HI)
     A                                  4  7'Field'
     A                                      DSPATR(HI)
     A                                  4 17'Attributes'
     A                                      DSPATR(HI)
     A                                  4 28'Text'
     A                                      DSPATR(HI)
     A                                  4 65'Options: 2=Edit'
     A                                      COLOR(BLU)
     A          R FOOTER
      *%%TS  SD  19980706  154553  MROWE       REL-V3R7M0  5716-PW1
     A                                      OVERLAY
     A                                 23  2'F1=Help'
     A                                      COLOR(BLU)
     A                                 23 12'F3=Exit'
     A                                      COLOR(BLU)
     A                                 23 22'F12=Previous'
     A                                      COLOR(BLU)
     A          R WINDOW1
     A*%%TS  SD  20010223  145932  MROWE       REL-V4R4M0  5769-PW1
     A                                      WINDOW(FOOTER2)
     A                                      CA03(03 'Exit')
     A                                      CF12(12 'Cancel')
     A                                      OVERLAY
     A                                  1 28'Field formatting rules'
     A                                      DSPATR(UL)
     A                                      DSPATR(HI)
     A            DA_INTF        1A  P
     A            DA_EXPF        1A  P
     A            S_IFLD        10A  O  2  2
     A            S_IITP         1A  O  2 13
     A            S_INLN         4A  O  2 15
     A            S_INSC         1A  O  2 20
     A            S_ITXT        52A  O  2 22
     A                                  3  2'Use rules:'
     A                                      DSPATR(HI)
     A            S_RULE         1A  B  3 13VALUES('Y' ' ')
     A                                  3 15'(Y)'
     A                                  3 19'Zero fill:'
     A                                      DSPATR(HI)
     A            S_ZFIL         1A  B  3 30VALUES('Y' ' ')
     A                                  3 32'(Y)'
     A                                  3 39'Negatives:'
     A                                      DSPATR(HI)
     A            S_NEGF         6A  B  3 51VALUES('*MINUS' '*FLOAT' '*CR' '*BR-
     A                                      KTS' '*NONE')
     A                                  3 59'Field prefix:'
     A                                      DSPATR(HI)
     A            S_PFIX         1A  B  3 73
     A                                  4  2'Date/Time:'
     A                                      DSPATR(HI)
     A            S_DATE         1A  B  4 13VALUES('Y' ' ')
     A                                  4 15'(Y)'
     A                                  4 19'Internal:'
     A                                      DSPATR(HI)
     A            S_INTF         8A  B  4 30VALUES('*CYMD' '*DMCY' '*MDCY' '*SY-
     A                                      MD' '*YMD' '*DMY' '*MDY' '*CYM' '*Y-
     A                                      M' '*MY' '*LILIAN' '*HMS' '*HM')
     A                                      DSPATR(&DA_INTF)
     A                                  4 39'Export as:'
     A                                      DSPATR(HI)
     A            S_EXPF         8A  B  4 50VALUES('*CYMD' '*DMCY' '*MDCY' '*SY-
     A                                      MD' '*YMD' '*DMY' '*MDY' '*CYM' '*Y-
     A                                      M' '*MY' '*LILIAN' '*HMS' '*HM')
     A                                      DSPATR(&DA_EXPF)
     A                                  5  2'Edit date/time:'
     A                                      DSPATR(HI)
     A            S_EDTD         1A  B  5 18
     A                                  5 20'(Y)'
     A                                  5 25'Separator:'
     A                                      DSPATR(HI)
     A            S_DSEP         1A  B  5 36
     A                                  5 39'Window year:'
     A                                      DSPATR(HI)
     A            S_WINY         2Y 0B  5 52EDTCDE(Z)
     A                                  5 56'Lilian 1:'
     A                                      DSPATR(HI)
     A            S_LILS          L  B  5 66
     A          R FOOTER2
      *%%TS  SD  19980706  154553  MROWE       REL-V3R7M0  5716-PW1
     A                                      OVERLAY
     A                                      WINDOW(*DFT 11 75)
     A                                      WDWBORDER((*COLOR GRN) (*DSPATR RI)-
     A                                       (*CHAR '        '))
     A                                  9  2'F1=Help'
     A                                      COLOR(BLU)
     A                                  9 12'F3=Exit'
     A                                      COLOR(BLU)
     A                                  9 22'F12=Previous'
     A                                      COLOR(BLU)
      *
     A          R MSFL                      SFL
     A                                      SFLMSGRCD(24)
     A            MSGKEY                    SFLMSGKEY
     A            SDS_PGM                   SFLPGMQ
      *
     A          R MSFLC                     SFLCTL(MSFL)
     A                                      OVERLAY
     A                                      SFLDSP
     A                                      SFLDSPCTL
     A                                      SFLINZ
     A  26
     AON26                                  SFLEND
     A                                      SFLSIZ(0002)
     A                                      SFLPAG(0001)
     A            SDS_PGM                   SFLPGMQ
      *
     A          R MSFLWIN                   SFL
     A                                      SFLMSGRCD(10)
     A            MSGKEY                    SFLMSGKEY
     A            SDS_PGM                   SFLPGMQ
      *
     A          R MSFLCWIN                  SFLCTL(MSFLWIN)
      *%%TS  SD  20010223  133037  MROWE       REL-V4R4M0  5769-PW1
     A                                      OVERLAY
     A                                      SFLDSP
     A                                      SFLDSPCTL
     A                                      SFLINZ
     A  26
     AON26                                  SFLEND
     A                                      SFLSIZ(0002)
     A                                      SFLPAG(0001)
     A                                      WINDOW(FOOTER2)
     A            SDS_PGM                   SFLPGMQ(10)

-- MartinRowe - 18 Jun 2005
Topic revision: r1 - 18 Jun 2005 - 20:35:37 - MartinRowe
 
This site is powered by FoswikiCopyright © by the contributing authors. All material on this collaboration platform is the property of the contributing authors.
Ideas, requests, problems regarding DBG/400? Send feedback